set test_script "sys.stp"
source $srcdir/$subdir/test.tcl

proc test_procedure {} {
    global srcdir subdir
    set wd [pwd]
    set flags ""
    if {$srcdir == ""} {
	set pattern "*.c"
    } else {
	set pattern "$srcdir/$subdir/*.c"
    }

    # for first pass, force 64-bit compilation for 64-bit systems
    # Add any other 64-bit arcvhitecture you want tested below.
    # To find tcl's platform name for your machine, run the following:
    # echo "puts $::tcl_platform(machine)" | tclsh

    switch -regexp $::tcl_platform(machine) {
	^ia64$ {
	    set do_64_bit_pass 1
	    set flags "" 
	}
	^(x86_64|ppc64|s390x)$ { 
	    set do_64_bit_pass 1
	    set flags "additional_flags=-m64"
	}
	default {
	    set do_64_bit_pass 0
	}
    }

    if {$do_64_bit_pass} {
	foreach filename [lsort [glob $pattern]] {
	    set testname [file tail [string range $filename 0 end-2]]
	    if {![installtest_p]} { untested "64-bit $testname"; continue }
	    send_log "Testing 64-bit ${testname} syscall\n"
	    run_one_test $filename $flags 64 "syscall"
	}
    }

    set do_32_bit_pass 1    
    switch -regexp $::tcl_platform(machine) {
	{^(x86_64|ppc64)$} { set flags "additional_flags=-m32" }
	{^s390x$} { set flags "additional_flags=-m31" }
	{^ia64$} { set do_32_bit_pass 0	}
    }

    if {$do_32_bit_pass} {
	foreach filename [lsort [glob $pattern]] {
	    set testname [file tail [string range $filename 0 end-2]]
	    if {![installtest_p]} { untested "32-bit $testname"; continue }
	    send_log "Testing 32-bit ${testname} syscall\n"
	    run_one_test $filename $flags 32 "syscall"
	}
    }
}

test_procedure
