## <summary>BIRD Internet Routing Daemon.</summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an bird environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`bird_admin',`
	gen_require(`
		type bird_t, bird_etc_t, bird_log_t;
		type bird_var_run_t, bird_initrc_exec_t;
	')

	allow $1 bird_t:process { ptrace signal_perms };
	ps_process_pattern($1, bird_t)

	init_labeled_script_domtrans($1, bird_initrc_exec_t)
	domain_system_change_exemption($1)
	role_transition $2 bird_initrc_exec_t system_r;
	allow $2 system_r;

	files_list_etc($1)
	admin_pattern($1, bird_etc_t)

	logging_list_logs($1)
	admin_pattern($1, bird_log_t)

	files_list_pids($1)
	admin_pattern($1, bird_var_run_t)
')
