## <summary>GNOME color manager</summary>

########################################
## <summary>
##	Execute a domain transition to run colord.
## </summary>
## <param name="domain">
## <summary>
##	Domain allowed access.
## </summary>
## </param>
#
interface(`colord_domtrans',`
	gen_require(`
		type colord_t, colord_exec_t;
	')

	domtrans_pattern($1, colord_exec_t, colord_t)
')

########################################
## <summary>
##	Send and receive messages from
##	colord over dbus.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`colord_dbus_chat',`
	gen_require(`
		type colord_t;
		class dbus send_msg;
	')

	allow $1 colord_t:dbus send_msg;
	allow colord_t $1:dbus send_msg;
	ps_process_pattern(colord_t, $1)
')

######################################
## <summary>
##	Read colord lib files.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`colord_read_lib_files',`
	gen_require(`
		type colord_var_lib_t;
	')

	files_search_var_lib($1)
	read_files_pattern($1, colord_var_lib_t, colord_var_lib_t)
')

########################################
## <summary>
##	Execute colord server in the colord domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`colord_systemctl',`
	gen_require(`
		type colord_t;
		type colord_unit_file_t;
	')

	systemd_exec_systemctl($1)
	init_reload_services($1)
	allow $1 colord_unit_file_t:file read_file_perms;
	allow $1 colord_unit_file_t:service manage_service_perms;

	ps_process_pattern($1, colord_t)
')
