## <summary>high-performance memory object caching system</summary>

########################################
## <summary>
##	Execute a domain transition to run memcached.
## </summary>
## <param name="domain">
## <summary>
##	Domain allowed to transition.
## </summary>
## </param>
#
interface(`memcached_domtrans',`
	gen_require(`
		type memcached_t;
		type memcached_exec_t;
	')

	domtrans_pattern($1, memcached_exec_t, memcached_t)
')

########################################
## <summary>
##	Read memcached PID files.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`memcached_read_pid_files',`
	gen_require(`
		type memcached_var_run_t;
	')

	files_search_pids($1)
	allow $1 memcached_var_run_t:file read_file_perms;
')

########################################
## <summary>
##	Manage memcached PID files
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`memcached_manage_pid_files',`
	gen_require(`
		type memcached_var_run_t;
	')

	files_search_pids($1)
	manage_files_pattern($1, memcached_var_run_t, memcached_var_run_t)
')

########################################
## <summary>
##	Connect to memcached over a unix stream socket.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`memcached_stream_connect',`
	gen_require(`
		type memcached_t, memcached_var_run_t;
	')

	files_search_pids($1)
	stream_connect_pattern($1, memcached_var_run_t, memcached_var_run_t, memcached_t)
')

########################################
## <summary>
##	All of the rules required to administrate 
##	an memcached environment
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	The role to be allowed to manage the memcached domain.
##	</summary>
## </param>
## <rolecap/>
#
interface(`memcached_admin',`
	gen_require(`
		type memcached_t, memcached_initrc_exec_t, memcached_var_run_t;
	')

	allow $1 memcached_t:process signal_perms;
	ps_process_pattern($1, memcached_t)
	tunable_policy(`deny_ptrace',`',`
		allow $1 memcached_t:process ptrace;
	')

	init_labeled_script_domtrans($1, memcached_initrc_exec_t)
	domain_system_change_exemption($1)
	role_transition $2 memcached_initrc_exec_t system_r;
	allow $2 system_r;

	files_list_pids($1)
	admin_pattern($1, memcached_var_run_t)
')
