## <summary>Clock speed measurement and manipulation.</summary>

########################################
## <summary>
##	Execute clockspeed utilities in
##	the clockspeed_cli domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`clockspeed_domtrans_cli',`
	gen_require(`
		type clockspeed_cli_t, clockspeed_cli_exec_t;
	')

	corecmd_search_bin($1)
	domtrans_pattern($1, clockspeed_cli_exec_t, clockspeed_cli_t)
')

########################################
## <summary>
##	Execute clockspeed utilities in the
##	clockspeed cli domain, and allow the
##	specified role the clockspeed cli domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`clockspeed_run_cli',`
	gen_require(`
		attribute_role clockspeed_cli_roles;
	')

	clockspeed_domtrans_cli($1)
	roleattribute $2 clockspeed_cli_roles;
')
