## <summary>Decode DMI data for x86/ia64 bioses.</summary>

########################################
## <summary>
##	Execute dmidecode in the dmidecode domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`dmidecode_domtrans',`
	gen_require(`
		type dmidecode_t, dmidecode_exec_t;
	')

	corecmd_search_bin($1)
	domtrans_pattern($1, dmidecode_exec_t, dmidecode_t)
')

######################################
## <summary>
##	Execute dmidecode in the caller domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`dmidecode_exec',`
	gen_require(`
		type dmidecode_exec_t;
	')

	corecmd_search_bin($1)
	can_exec($1, dmidecode_exec_t)
')

########################################
## <summary>
##	Execute dmidecode in the dmidecode
##	domain, and allow the specified
##	role the dmidecode domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`dmidecode_run',`
	gen_require(`
		attribute_role dmidecode_roles;
	')

	dmidecode_domtrans($1)
	roleattribute $2 dmidecode_roles;
')
