/*
 * Copyright (c) 2008-2014 MongoDB, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *   http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'idea'
apply plugin: 'osgi'

archivesBaseName = 'mongo-java-driver'

idea {
    module {
        sourceDirs = [] // Ignore in idea (prevents intellij crashing due to sources outside project dir)
    }
}

// dependencies copied from driver-core
dependencies {
    compile "io.netty:netty-buffer:$nettyVersion", optional
    compile "io.netty:netty-transport:$nettyVersion", optional
    compile "io.netty:netty-handler:$nettyVersion", optional
    compile "org.xerial.snappy:snappy-java:$snappyVersion", optional
}

// srcDirs copied as well, so everything is compiled twice
sourceSets {
    main {
        java {
            srcDirs = ["$rootDir/driver/src/main", "$rootDir/driver-core/src/main", "$rootDir/bson/src/main"]
        }
    }
}

// copied from driver-core
jar {
    manifest {
        instruction 'Build-Version', getGitVersion()
        instruction 'Import-Package',
                    'javax.xml.bind.*',
                    'javax.crypto.*',
                    'javax.crypto.spec.*',
                    'javax.management.*',
                    'javax.naming.spi.*',
                    'javax.net.*',
                    'javax.net.ssl.*',
                    'javax.security.sasl.*',
                    'javax.security.auth.callback.*',
                    'org.ietf.jgss.*',
                    'io.netty.*;resolution:=optional',
                    'org.xerial.snappy.*;resolution:=optional',
                    'org.slf4j;resolution:=optional'
    }
    }

modifyPom {
    project {
        name 'MongoDB Java Driver'
        description 'The MongoDB Java Driver uber-artifact, containing mongodb-driver, mongodb-driver-core, and bson'
        url 'http://www.mongodb.org'
    }
}
